cfcol

Description

Defines table column header, width, alignment, and text. Used within a cftable tag.

Syntax

<cfcol 
   header = "column_header_text"
   width = "number_indicating_width_of_column"
   align = "left" or "right" or "center"
   text = "column_text">

History

ColdFusion MX: Added the ability to construct dynamic cfcol statements.

Attribute	Req/Opt	Default	Description
header	Required		Column header text. To use this attribute, you must also use the `cftable` `colHeaders` attribute.
width	Optional	20	Column width. If the length of data displayed exceeds this value, data is truncated to fit. To avoid this, use an HTML `table` tag. If the surrounding `cftable` tag includes the `htmltable` attribute, `width` specifies the percent of the table width and it does not truncate text; otherwise, `width` specifies the number of characters.
align	Optional	left	Column alignment: left right center
text	Required		Double-quotation mark-delimited text; determines what to display. Rules: same as for `cfoutput` sections. You can embed hyperlinks, image references, and input controls.

Usage

At least one cfcol tag is required within the cftable tag. You must put cfcol and cftable tags adjacent in a page. The only tag that you can nest within the cftable tag is the cfcol tag. You cannot nest cftable tags.

To display the cfcol header text, you must specify the cfcol header and the cftable colHeader attribute. If you specify either attribute without the other, the header does not display. No error is thrown.

Example

<!--- This example shows the use of cfcol and cftable to align 
information returned from a query. --->
<!--- query selects information from cfdocexamples data source. --->
<cfquery name = "GetEmployees" dataSource = "cfdocexamples">
   SELECT Emp_ID, FirstName, LastName, EMail, Phone, Department
   FROM Employees
</cfquery>
<html>
<body>
<h3>cfcol Example</h3>
<!--- Uses the HTMLTable attribute to display cftable as an HTML 
table, rather than PRE formatted information --->
<cftable 
   query = "GetEmployees" 
   startRow = "1" colSpacing = "3" 
   HTMLTable colheaders>
<!--- Each cfcol tag sets the width of a column in the table, 
the header information, and the text/CFML for the cell. --->
   <cfcol header = "<b>ID</b>"
      align = "Left"
      width = 2
      text  = "#Emp_ID#">
   <cfcol header = "<b>Name/Email</b>"   
      align = "Left"
      width = 15
      text  = "<a href = 'mailto:#Email#'>#FirstName# #LastName#</A>">
   <cfcol header = "<b>Phone Number</b>"
      align = "Center"
      width = 15
      text  = "#Phone#">
</cftable>

View comments in LiveDocs