cfcomponent

Description

Creates and defines a component object; encloses functionality that you build in CFML and enclose within cffunction tags. This tag contains one or more cffunction tags that define methods. Code within the body of this tag, other than cffunction tags, is executed when the component is instantiated.

A component file has the extension CFC and is stored in any directory of an application.

A component method is invoked in the following ways:

Within the cfinvoke tag in a ColdFusion page
Within a URL that calls a CFC file and passes a method name as a URL parameter
Within the cfscript tag
As a web service
From Flash code

Syntax

<cfcomponent
   extends ="anotherComponent"
   output = "yes" or "no"
   style = "rpc" or "document"
   namespace = "default service namespace"
   serviceportname = "port element name"
   porttypename = "porttype element name"
   bindingname = "binding element name"
   wsdlfile = "path to hard-coded wsdl file"
   displayname = "text string">
   hint = "text string">
   variable declarations
   <cffunction ...>
      ...
   </cffunction> 

   <cffunction ...>
      ...
   </cffunction> 
</cfcomponent>

History

ColdFusion MX 7:

Added support for publishing document-literal style web services.
Added the style, namespace, serviceportname, porttypename, wsdlfile, and bindingname attributes.
Extended functionality for the hint and displayname attributes when publishing document-literal style web services.

ColdFusion MX: Added this tag.

Attributes

Attribute	Req/Opt	Default	Description
extends	Optional		Name of parent component from which to inherit methods and properties.
output	Optional	Component body displayable text is processed as standard CFML	Specifies whether constructor code in the component can generate HTML output; does not affect output in the body of `cffunction` tags in the component`.` yes: Constructor code is processed as if it were within a `cfoutput` tag. Variable names surrounded by number signs (#) are automatically replaced with their values. no: Constructor code is processed as if it were within a `cfsilent` tag. If you do not specify this attribute, constructor code is processed as standard CFML. Any variables must be in `cfoutput` tags.
style	Optional	rpc	Specifies whether a CFC used for web services uses RPC-encoded style or document-literal style: rpc: RPC-encoded style document: document-literal style
namespace	Optional	classname	Specifies the namespace used in the WSDL when using the CFC as a document-literal style web service. If you don't specify this attribute, ColdFusion MX derives the value from the CFC class name. This attribute applies only when `style="document"`.
serviceportname	Optional		Specifies the `name` attribute of the `port` element in the WSDL. If you don't specify this attribute, ColdFusion MX derives the value from the CFC class name. This attribute applies only when `style="document"`.
porttypename	Optional		Specifies the `name` attribute of the `porttype` element in the WSDL. If you don't specify this attribute, ColdFusion MX derives the value from the CFC class name. This attribute applies only when `style="document"`.
bindingname	Optional		Specifies the `binding` attribute of the `port` element in the WSDL. If you don't specify this attribute, ColdFusion MX derives the value from the CFC class name. This attribute applies only when `style="document"`.
wsdlfile	Optional		A properly formatted WSDL file to be used instead of WSDL generated by ColdFusion MX. This attribute applies only when `style="document"`.
displayname	Optional		A string to be displayed when using introspection to show information about the CFC. The information appears on the heading, following the component name. If the `style` attribute is set to document, ColdFusion MX uses the `displayname` attribute as the `name` attribute of the `service` element in the WSDL.
hint	Optional		Text to be displayed when using introspection to show information about the CFC. The `hint` attribute value appears below the component name heading. This attribute can be useful for describing the purpose of the parameter. If the `style` attribute is set to document, ColdFusion MX uses the `hint` attribute as the content of the `documentation` element of the service in the WSDL.

Usage

If you specify the extends attribute, the data and methods of the parent component are available to CFC methods as if they were parts of the current component. If the managerCFC component extends the employeeCFC component, and the employeeCFC component has a getEmployeeName method, you can call this method using the managerCFC, as follows:

<cfinvoke component="managerCFC" method="getEmployeeName" returnVariable="managerName" EmployeeID=#EmpID#>

This tag requires an end tag.

If you specify style="document", ColdFusion MX publishes the CFC as a document-literal style web service. For more information, see Publishing document-literal style web services in Using Web Services in ColdFusion MX Developer's Guide.

Example

<cfcomponent>
   <cffunction name="getEmp">
       <cfquery name="empQuery" datasource="cfdocexamples" >
          SELECT FIRSTNAME, LASTNAME, EMAIL
          FROM tblEmployees
       </cfquery>
       <cfreturn empQuery>
   </cffunction>

   <cffunction name="getDept">
      <cfquery name="deptQuery" datasource="cfdocexamples" >
          SELECT *
          FROM tblDepartments
       </cfquery>
       <cfreturn deptQuery>
   </cffunction>
</cfcomponent>

View comments in LiveDocs